retour index

chapitre7

Bifurcations

Points fixes et stabilité

Variétés stables et instables

Bifurcations génériques

Autres bifurcations

Bifurcation de Hopf

Phénomène d'hystérésis

 

Points fixes et stabilité

Les propriétés des systèmes dynamiques non linéaires, qui évoluent au cours du temps, sont étroitement liées à l'évolution des points d'équilibre du système. Tout changement dans leur nombre ou leur stabilité se répercute parfois de façon dramatique sur le comportement du système. De plus, ces changements se font suivant un petit nombre de scénarios qui permettent d'esquisser une classification des changements de comportements.

D'où l'intérêt d'étudier les points fixes et leur stabilité, les bifurcations qui accompagnent les changements qualitatifs du système, et les suites de bifurcations qui constituent les cascades.

Application à une dimension

Etant donnée une application f d'un espace dans lui-même, x un point qui est la valeur initiale, l'ensemble des points MATH est l'orbite de x. Un point p est un pointfixe de l'application si f(p) = p. C'est également un point d'équilibre du système dont l'évolution est décrite par l'itération de l'application f.

L'itération peut être suivie de façon graphique par le graphe en toile d'araignée (voir figure ci-dessous).

Un point fixe p est attracteur et c'est un puits, si tous les points suffisamment proches de p sont attirés vers p. Il est stable.

Il est repousseur (ou répulsif) et c'est une source, si tous les points suffisamment proches de p sont repoussés par p. Il est instable.

Pour une application à une dimension sur R, supposée infiniment dérivable, on a un théorème qui dit que
MATH

En effet, si la pente de la dérivée est $<1$ en valeur absolue, le point se rapproche de p, comme on peut le voir facilement sur le graphe en toile d'araignée, et il s'en éloigne si la pente devient >1 en valeur absolue.

On a en fait 4 cas possibles :
MATH

Prenons l'exemple de $f(x)=2x(1-x)$ :

> restart:with(plots):

> f:=x->2*x*(1-x):

> x:=0.2:y:=f(x):s:=[x,0]: to 10 do

s:=s,[x,y],[y,y];x:=y;y:=f(x):od:

> x:=-0.1:y:=f(x):s1:=[x,0]: to 3 do

s1:=s1,[x,y],[y,y];x:=y;y:=f(x):od:

> plot({f,t->t,[s],[s1]},-1..1,-1..1,color=red,axes=boxed);


chap7__7.pngfigure 7.1 : puits et source pour la fonction $f(x)=2x(1-x)$

Calculons les points fixes et leurs dérivées :

> x:='x':s:=solve(f(x)=x,x);
MATH

> D(f)(0),D(f)(0.5);
MATH

L'origine, pour laquelle la valeur de la dérivée est 2, est une source ;le point (1/2,1/2), pour lequel la dérivée est nulle, est un puits. La dérivée étant nulle, la convergence est rapide ;le point (1/2,1/2) est un point fixe superattractif.

On peut trouver également des points périodiques. Un point est périodique de période k si k est le plus petit entier positif tel que $f^{k}(p)=p.$ L'orbite de période k de p est un puits périodique si p est un puits pour l'application $f^{k}$ et une source périodique si p est une source pour l'application $f^{k}.$

La dérivée d'une fonction composée se calculant par la règle de la chaine
MATH

on en déduit que
MATH

Si x est un point de période 2, la dérivée de $f^{2}$ est le produit des dérivées de f aux 2 points de l'orbite. La dérivée de $f^{2}$ est donc la même aux 2 points de l'orbite de période 2.

Ceci se généralise aisément, et l'on obtient le résultat suivant :si MATH est une orbite de période k de f, alors


MATH

Prenons un exemple de cycle attracteur de période 2 :

> restart:with(plots):

> f:=x->3.1*x*(1-x):

> x:=0.65:y:=f(x):s:=[x,0]: to 50 do s:=s,[x,y],[y,y];x:=y;y:=f(x):od:

> plot({f,t->t,[s]},0..1,0..1,color=red,axes=boxed);


chap7__20.pngfigure 7.2 : cycle attracteur de période 2 pour $f(x)=3,2x(1-x)$

Les deux points de la courbe formant l'orbite périodique sont [.5580238458, .7645630232] et [.7645630232, .5580198611]. Calculons les dérivées de $f^{2}$ en ces points :

> D(f@@2)(0.7645630232),D(f@@2)(0.5580198611);
MATH

qui sont identiques aux imprécisions de calcul près ;le produit est < 1, ce qui confirme que l'orbite est attractive.

Application à deux dimensions

Dans le cas d'un espace à deux dimensions, un nouveau type de point fixe apparait, appelé point-selle ;un point-selle a au moins une direction attractive et au moins une direction repulsive.

Soit MATH $,$ $x).$ C'est une version de l'application de Hénon. On a deux points fixes :(0,0) et (-0,6, -0,6) (voir calcul ci-dessous).

On prend 180 points formant un cercle de rayon 0,2 autour des 2 points fixes, et on applique l'itération, d'abord une fois, puis deux fois :

> restart:with(plots):with(plottools):

> solve({x=-x^2+0.4*y,y=x},{x,y});
MATH

> f:=proc(x,y) local z,a,b: a:=-x^2+0.4*y:a,x end:

> liste1:=seq(Re(evalc(polar(0.2,i*evalf(Pi)/90))),i=1..180):

> liste2:=seq(Im(evalc(polar(0.2,i*evalf(Pi)/90))),i=1..180):

>p:=seq(pointplot([seq((f@@i)([liste1][j],[liste2][j]),j=1..180)]),i=0..2):

> liste1:=seq(-0.6+Re(evalc(polar(0.2,i*evalf(Pi)/90))),i=1..180):

> liste2:=seq(-0.6+Im(evalc(polar(0.2,i*evalf(Pi)/90))),i=1..180):

>q:=seq(pointplot([seq((f@@i)([liste1][j],[liste2][j]),j=1..180)]),i=0..2):

> display(p,q,rectangle([-0.01,0.01],[0.01,-0.01]),

rectangle([-0.61,-0.59],[-0.59,-0.61]),color=red);


chap7__27.pngfigure 7.3 : point fixe attracteur et point-selle d'une application de Hénon

On constate qu'autour de l'origine, le cercle se contracte et que l'origine attire les points :il s'agit d'un puits.

Le cercle autour du second point fixe (-0,6, -0,6) se déforme en se rétrécissant dans une direction attractive et en s'étirant dans une autre direction qui est la direction repulsive :il s'agit d'un point-selle.

Pour un système linéaire, décrit par une matrice 2$\times 2,$ la diagonalisation de la matrice conduit le plus souvent à une matrice de la forme
MATH

a et b étant les valeurs propres de l'application linéaire, sopposées ici distinctes.

L'origine est un point fixe, qui est attractif si $\left| a\right| $ et MATH répulsif si $\left| a\right| $ et $\left| b\right| >1$ ;c'est un point-selle si

MATH Alors l'orbite d'un point porté par le vecteur propre correspondant à a se rapproche de l'origine et l'orbite d'un point porté par le vecteur propre correspondant à b s'en éloigne.

Si l'application est non linéaire, comme c'est le cas de l'application de Hénon considérée plus haut, il faut considérer la matrice jacobienne, qui, pour l'application de Hénon MATH s'écrit
MATH

Avec a = 0 et b = 0,4 dans l'exemple plus haut, cela donne à l'origine
MATH

qui a pour valeurs propres $\pm \sqrt{0,4}$ :

> A:=matrix(2,2,[0,0.4,1,0]):

> eigenvalues(A);
MATH

L'origine est donc un puits.

Pour le point fixe (-0,6, -0,6), on obtient
MATH

> A:=matrix(2,2,[1.2,0.4,1,0]):

> eigenvalues(A);
MATH

C'est bien un point-selle.

Pour un point périodique MATH, il faut regarder les valeurs propres de la matrice
MATH

d'après la règle de la chaine. Cette matrice peut se calculer en fait en n'importe quel point de l'orbite périodique.

début chapitre

Variétés stables et instables

Etant donné un point-selle p, la variété stable de p est l'ensemble des points dont les itérés par la transformation convergent vers p, et la variété instable l'ensemble des points dont les itérés par la transformation inverse convergent vers p, c'est-à-dire dont les itérés anterieurs par la transformation proviennent de p.

Le théorème de l'ensemble stable, pour une application à deux dimensions, nous enseigne que dans le cas général, les deux variétés, stable et instable, sont des courbes. La variété stable est donc la courbe dont les itérés convergent vers le point-selle et la variété instable la courbe formée par les itérés provenant du point-selle.

On va tracer les variétés stable et instable du point-selle de la transformation de Hénon
MATH

Pour cela, on cherche d'abord le point-selle :

> restart:with(linalg):with(plots):

> solve({x=-x^2+0.4*y,y=x},{x,y});
MATH

Le point (0,0) est un point-fixe stable, comme on peut le vérifier avec la matrice jacobienne.

Quand au point fixe (-0.6, -0.6), la matrice jacobienne en ce point s'écrit :

> A:=matrix(2,2,[1.2,0.4,1,0]);
MATH

Cherchons les valeurs propres et les vecteurs propres :

> t:=eigenvectors(A);
MATH

L'une des 2 valeurs propres proche de - 0,27 est comprise entre - 1 et 1, l'autre, proche de 1,47 est supérieure à 1 ;on a donc affaire à un point-selle.

Isolons le vecteur propre correspondant à la variété instable :

> t1:=op(2,[t]);
MATH

> t2:=op(op(3,t1));
MATH

>whattype(t2);
MATH

Il faut transformer t2 en liste :

> t3:=convert(t2,list);
MATH

> t4:=op(t3);
MATH

On définit la transformation de Hénon :

> f:=proc(x,y) :-x^2+0.4*y,x end:

On forme liste1 et liste2 qui sont les abcisses et ordonnées de 201 points pris de part et d'autre du point fixe sur le vecteur propre de façon régulière entre le point fixe et le point du vecteur propre correspondant à la valeur propre 1,47, situé à une distance égale à 0,01 du point fixe. On prend le 12$^{i\grave{e}me}$ itéré de tous ces points et on trace le graphe correspondant, noté p1. On a ainsi obtenu la variété instable :c'est une courbe qui, d'un côté se dirige vers l'origine (point fixe attracteur dans son bassin d'attraction), et de l'autre vers l'infini

> liste1:=seq(-0.6+op(1,[t4])*1e-2*i/100,i=-100..100):

> liste2:=seq(-0.6+op(2,[t4])*1e-2*i/100,i=-100..100):

> p:=pointplot([seq((f@@12)([liste1][j],[liste2][j]),j=1..200)]):

> display(p,color=red);

Recommençons avec l'application inverse pour avoir la variété stable. Cherchons d'abord la transformation inverse :

> solve({x=-a^2+0.4*b,y=a},{a,b});
MATH

puis on effectue les mêmes opérations que précédemment :

> A:=matrix(2,2,[0,1,2.5,5*(-0.6)]);

> t:=eigenvectors(A);
MATH

>t1:=op(2,[t]):t2:=op(op(3,t1)):

t3:=convert(t2,list):t4:=op(t3);
MATH

> f:=proc(x,y) :y,2.5*x+2.5*y^2 end:

> liste1:=seq(-0.6+op(1,[t4])*1e-2*i/100,i=-100..100):

> liste2:=seq(-0.6+op(2,[t4])*1e-2*i/100,i=-100..100):

> p:=pointplot([seq((f@@6)([liste1][j],[liste2][j]),j=1..200)]):

> display(p,color=red,view=[-2..3,-4..10]);

>display(p1,p2,view=[-2..2,-2..10]);


chap7__58.pngfigure 7.4 : variétés stable et instable de l'application de Hénon MATH

La variété stable en forme de croissant est la frontière séparant les bassins d'attraction du point fixe à l'origine et de l'infini. On constate que les deux variétés ne se coupent pas en dehors du point-selle.

Si on recommence avec la transformation de Hénon
MATH

avec le point fixe $\simeq $ $(0,94,$ $0,94),$ on trouve la figure suivante


chap7__64.pngfigure 7.5 : variétés stable et instable de la transformation de Hénon MATH

La variété instable, essenciellement horizontale, est en fait très proche de l'attracteur étrange de la transformation de Hénon, ce qui s'explique par le fait que l'attracteur de Hénon attire tous les points de son bassin d'attraction.

La variété stable se compose d'une infinité de feuillets (dont la figure ne donne qu'une idée) en forme de croissants. Les deux variétés ont une structure fractale. Ces deux variétés se coupent en des points nommés points homocliniques qui sont par définition les points appartenant simultanément aux variétés stable et instable du même point-selle.

S'il existe un point homoclinique, il en existe une infinité :en effet tous les itérés du point appartiennent également aux variétés stable et instable et sont des points homocliniques. La présence de points homocliniques implique que le système a des orbites chaotiques. La sensibilité aux conditions initiales, qui, en l'absence de point homoclinique, n'existe que pour le point-selle, s'étend à une portion étendue de l'espace en cas de points homocliniques.

Oscillateur anharmonique libre

On va tracer les variétés stable et instable du point-selle de l'oscillateur anharmonique libre (voir chapitre 9).

Cet oscillateur, appelé encore oscillateur à deux puits ou oscillateur de Duffing a pour équation lorsqu'il est libre et amorti
MATH

Ses points fixes satisfont à $-x+x^{3}=0,$ soit $x=0$ et $x=\pm 1.$

On peut écrire l'équation différentielle précédente comme un système de deux équations différentielles du premier ordre
MATH

dont la matrice jacobienne est
MATH

En $x=0,$ cette matrice s'écrit

>restart:with(linalg):with(DEtools):

>A:=matrix(2,2,[0,1,1,-0.1]);
MATH

>eigenvectors(A);
MATH

Une des valeurs propres est inférieure à 1 et l'autre est supérieure à 1 :on a affaire à un point-selle.

On prend 2 points sur le vecteur propre correspondant à la valeur propre supérieure à 1 de part et d'autre de l'origine à une distance 0,01 de celle-ci, et l'on trace les trajectoires de phase arrivant en ces points (c'est la variété stable) et partant de ces points (c'est la variété instable aboutissant aux puits). Les trajectoires sont tracées simultanément en prenant t <0 et t >0.

> phaseportrait([D(x)(t)=u,D(u)(t)=x-x^3-0.1*u],[x,u],t=-20..40,

[[x(0)=0.0689,u(0)=-0.0724],[x(0)=-0.0689,u(0)=+0.0724]],

stepsize=0.1,scene=[x,u],linecolor=red,arrows=none);


chap7__74.pngfigure 7.6 : variétés stable et instable de l'oscillateur anharmonique amorti

Les deux courbes arrivant à l'origine qui constituent la variété stable délimitent les bassins d'attraction des deux puits (une couche vers l'un, une couche vers l'autre).

début chapitre

Bifurcations génériques

Lorsque le comportement d'un système dépend d'un ou plusieurs facteurs, les équations qui décrivent ce comportement dépendent d'un ou plusieurs paramètres de contrôle.

Pour certaines valeurs de ces paramètres de contrôle, il y a changement qualitatif dans le comportement du système, correspondant à une variation dans le nombre ou la stabilité des points fixes. On a affaire à une bifurcation. Les bifurcations génériques sont celles qui ont lieu habituellement et qui ne sont pas des cas particuliers.

Bifurcation selle-noeud

On considère la famille d'applications quadratiques $f(a,x)=a-x^{2}.$

A chaque valeur du paramètre de contrôle a correspond une transformation différente. Les points fixes satisfont à $f(a,x)=x,$ ce sont les intersections des 2 courbes $y=x$ et $y=a-x^{2}.$ Traçons les deux courbes pour a = -1, -0,25 et 0,5 :

> restart: with(plots):with(linalg):

> a:=-1:p1:=plot({x->x,x->a-x^2},-2..2,color=red):

> a:=-0.25:p2:=plot({x->x,x->a-x^2},-2..2,color=red):

> a:=0.5:p3:=plot({x->x,x->a-x^2},-2..2,color=red):

> A:=matrix(1,3,[p1,p2,p3]):

> display(A);


chap7__82.pngfigure 7.7 : application quadratique avec $a=-1,$ $-0.25$ et $0,5$

Pour a = -1, il n'y a pas d'intersection, donc pas de point fixe.

Pour a = -0,25, les deux courbes sont tangentes, on a apparition de deux points fixes confondus.

Pour a = 0,5, on a deux points fixes, dont l'un est est un puits (pour x>0) et l'autre une source, comme on peut le vérifier en traçant la suite des itérés en toile d'araignée de part et d'autre du point fixe.

Pour la valeur de bifurcation a = -0,25 du paramètre, le système, qui n'avait pas de point fixe, se met à un posséder deux, un puits (ou noeud) et un point-selle (source pour une itération à une dimension). La bifurcation se nomme bifurcation selle-noeud.

On peut tracer le diagramme de bifurcation, en portant l'abcisse des points fixes en fonction de la valeur du paramètre a :

> restart:with(plots):

> solve(x=a-x^2,x);

> p1:=plot(-0.5+0.5*(1+4*a)^0.5,a=-0.25..0.75,x=-1.5..0.5):

> p2:=plot(-0.5-0.5*(1+4*a)^0.5,a=-0.25..0.75,linestyle=4):

> display(p1,p2);


chap7__83.pngfigure 7.8 : diagramme de bifurcation selle-noeud

Pour la valeur a = -0,25, il y a apparition de deux points fixes, dont l'un est un puits (courbe solide) et l'autre un point fixe instable, qui est ici une source (courbe en pointillés).

L'apparition de cette bifurcation se signale souvent par un phénomène d'intermittence (voir chapitre 8 et application logistique).

Bifurcation par doublement de période

L'autre type le plus fréquent de bifurcation est la bifurcation par doublement de période.

Reprenons l'exemple de l'application quadratique $f(a,x)=a-x^{2}.$

Traçons l'application quadratique pour a = 0,5, 0,75 et 0,9, ainsi que la première bissectrice et la toile d'araignée correspondant à l'itéré d'un point initial arbitraire :

> f:=x->0.5-x^2:x:=-1:s:=[x,-3]:n:=10:

for i to n do y:=f(x):s:=s,[x,y],[y,y]:x:=y od:

> p1:=plot({f,t->t,[s]},-2..2,-3..2,color=black):

> f:=x->0.75-x^2:x:=-1:s:=[x,-3]:n:=100:

for i to n do y:=f(x):s:=s,[x,y],[y,y]:x:=y od:

> p2:=plot({f,t->t,[s]},-2..2,-3..2,color=black):

> f:=x->0.9-x^2:x:=0.4:s:=[x,-3]:n:=20:

for i to n do y:=f(x):s:=s,[x,y],[y,y]:x:=y od:

> p3:=plot({f,t->t,[s]},-2..2,-3..2,color=black):

> with(linalg):A:=matrix(1,3,[p1,p2,p3]): display(A);


chap7__88.pngfigue 7.9 : application quadratique et toile d'araignée pour $a=0,5,$ $0,75$ et $0,9$

Pour a = 0,5, il y a un point fixe attractif qui est un puits et les itérés se dirigent vers ce point.

Pour a = 0,75, il en est de même, mais la convergence est beaucoup plus lente car la pente au point fixe est égale à -1.

Lorsque a dépasse la valeur 0,75, par exemple 0,9 comme dans le dernier cas, les orbites sont attirés vers un puits de période 2 ;il y a un phénomène de doublement de période et on a une bifurcation par doublement de période.

On trace le diagramme de bifurcation, sachant que les points fixes après doublement de période sont ceux de la seconde itération de l'application quadratique :

> f:=x->a-x^2;

> solve((f@@2)(x)=x,x);
MATH

> p1:=plot(0.5+0.5*(-3+4*a)^0.5,a=0.75..1,x=0..1):

> p2:=plot(0.5-0.5*(-3+4*a)^0.5,a=0.75..1):

> p3:=plot(-0.5+0.5*(1+4*a)^0.5,a=0.5..0.75):

> p4:=plot(-0.5+0.5*(1+4*a)^0.5,a=0.75..1,linestyle=2):

> display(p1,p2,p3,p4);


chap7__90.pngfigure 7.10 : diagramme de bifurcation par doublement de période

Pour la valeur de bifurcation a = 0,75, le point fixe devient instable, et il y a apparition de deux points fixes stables de période 2. Ce phénomène se répète à son tour pour a = 1,25 où l'on a une nouvelle bifurcation par doublement de période aboutissant en fait à une cascade de doublement de période menant au chaos.

début chapitre

Autres bifurcations

Il existe, pour les systèmes à une variable, d'autres types de bifurcations, mais qui ne sont pas génériques, c'est-à-dire qui sont des cas particuliers possédant des symétries particulières.

Soit l'application logistique $f(x)=ax(1-x).$

Traçons la courbe ainsi que la première bissectrice pour a = 0,6, 1 et 2.

> restart:with(plots):with(linalg):

> f:=x->a*x*(1-x);

> a:=0.6:p1:=plot({f,t->t},-0.8..1,color=black,tickmarks=[4,3]):

> a:=1:p2:=plot({f,t->t},-0.5..1,color=black,tickmarks=[4,3]):

> a:=2:p3:=plot({f,t->t},-0.3..1,color=black,tickmarks=[3,3]):

> A:=matrix(1,3,[p1,p2,p3]):

> display(A);


chap7__95.pngfigure 7.11 : application logistique pour $a=0,6,$ $1$ et $2$

Pour a = 0,6, on a 2 points fixes, l'origine étant stable et l'autre instable.

Pour a = 1, les 2 points fixes se confondent ;c'est la valeur de bifurcation.

Pour a = 2, on a à nouveau 2 points fixes, mais l'origine est maintenant instable et l'autre stable.

On a un changement de stabilité des 2 points fixes lorsque le paramètre passe par la valeur 1. La bifurcation correspondante s'appelle bifurcation transcritique (avec échange de stabilité).

Traçons le diagramme de bifurcation correspondant :

> p1:=plot(0,a=0..1,x=-0.5..0.6,thickness=2):

> p2:=plot(0,a=1..2,x=-0.5..0.6,thickness=2,linestyle=2):

> p3:=plot((a-1)/a,a=1..2,x=-0.5..0.6,thickness=2):

> p4:=plot((a-1)/a,a=0.5..1,x=-0.5..0.6,thickness=2,

linestyle=2):

> display(p1,p2,p3,p4);


chap7__96.pngfigure 7.12 : diagramme d'une bifurcation transcritique

Prenons comme autre exemple $f(x)=x^{3}-ax$ que nous traçons pour a = -2, -1 et 0 :

> restart:with(plots):with(linalg):

> f:=x->x^3-a*x;

> a:=-2:p1:=plot({f,t->t},-1..1,color=black,tickmarks=[3,3]):

> a:=-1:p2:=plot({f,t->t},-1.1..1.1,color=black,tickmarks=[3,3]):

> a:=0:p3:=plot({f,t->t},-1.2..1.2,color=black,tickmarks=[3,3]):

> A:=matrix(1,3,[p1,p2,p3]):

> display(A);


chap7__100.pngfigure 7.13 : application $f(x)=x^{3}-3x$ pour $a=-2,$ -1 et 0

Pour a = -2, un seul point fixe instable à l'origine.

Pour a = -1, on est à la bifurcation, et, pour a = 0, on a 3 points fixes ;l'origine est devenue stable et les 2 autres points sont instables. D'où le diagramme de bifurcation :

> a:='a':solve(f(x)=x,x);

> p1:=plot(0,a=-2..-1,x=-2..2,thickness=2,linestyle=2):

> p2:=plot(0,a=-1..2,x=-2..2,thickness=2):

> p3:=plot((a+1)^0.5,a=-1..2,x=-2..2,thickness=2,linestyle=2):

> p4:=plot(-(a+1)^0.5,a=-1..2,x=-2..2,thickness=2,linestyle=2):

> display(p1,p2,p3,p4);


chap7__101.pngfigure 7.14: diagramme de bifurcation fourche

Il s'agit d'un diagramme de bifurcation fourche, d'après la forme du tracé. Cette bifurcation est due à la symétrie de l'application par rapport à l'origine. Il s'agit ici d'une bifurcation sous-critique ;la bifurcation supercritique change la stabilité des points fixes (l'origine est d'abord stable, puis instable).

On peut résumer les 4 types de bifurcation précédents d'après la valeur des dérivées prises pour les valeurs de bifurcation :
MATH

Ce qui a été dit pour les applications à une variable reste vrai pour les applications planes à 2 variables (du type application de Hénon) pour les systèmes dissipatifs ;la seule différence réside dans le fait que les points instables des bifurcations selle-noeud et doublement de période sont maintenant des point-selles et non des sources.

début chapitre

Bifurcation de Hopf

Dans le cas des équations différentielles, les solutions périodiques peuvent être attractives si elles attirent les solutions voisines ou répulsives. On peut là encore avoir des bifurcations selle-noeud, où l'on a apparition simultanée d'une trajectoire périodique stable et d'une trajectoire périodique instable et des bifurcations par doublement de période, où la trajectoire périodique stable devient instable cependant qu'apparait une trajectoire stable de période double. Ces résultats peuvent se retrouver en utilisant une carte de Poincaré et l'application de Poincaré de premier retour associée. Les valeurs propres de la matrice jacobienne associée à l'application de Poincaré sont les multiplicateurs de Floquet de la trajectoire périodique et la théorie se calque sur celle des itérations.

Il existe pourtant un autre type de bifurcation générique où des trajectoires périodiques peuvent prendre naissance :ce sont les bifurcations de Hopf. Voyons le sur un exemple.

Soit le système d'équations différentielles
MATH

L'origine est un point fixe pour toutes les valeurs de a.

Traçons, en projection sur le plan (x,y), des trajectoires de phase pour a < 0 et a > 0 ;tout d'abord pour a = -0,1 :

>restart:with(DEtools):

>phaseportrait({D(x)(t)=-y+x*(-0.1-x^2-y^2),

D(y)(t)=x+y*(-0.1-x^2-y^2)},{x,y},t=0..40,[[x(0)=0,y(0)=0.5]],

stepsize=0.1,scene=[x,y],scaling=constrained,linecolor=black);


chap7__105.pngfigure 7.15 : trajectoire de phase pour a < 0

La trajectoire de phase se dirige vers le point fixe à l'origine. Recommençons, avec a = 0,1 et 2 valeurs initiales :

> phaseportrait({D(x)(t)=-y+x*(0.1-x^2-y^2),

D(y)(t)=x+y*(0.1-x^2-y^2)},{x,y},t=0..25,

[[x(0)=0,y(0)=0.8],[x(0)=0,y(0)=0.1]],stepsize=0.1,

scene=[x,y],scaling=constrained,linecolor=black);


chap7__106.pngfigure 7.16 : trajectoires de phase pour a > 0 et 2 valeurs initiales

On voit que, quelle que soit la condition initiale, la trajectoire se dirige vers un cercle dont le rayon est $\sqrt{a}$, d'équation MATH comme on peut le vérifier sur les équations. Le cercle est une solution périodique attractive. En a = 0, on a une bifurcation de Hopf :l'origine devient instable et il apparait une solution périodique stable, comme on peut le voir sur le diagramme de bifurcation où l'on trace le rayon r du cercle en fonction de a :

> p1:=plot(0,a=-2..0,thickness=2):

> p2:=plot(0,a=0..2,thickness=2,linestyle=2):

> p3:=plot(sqrt(a),a=0..2,r=-0.1..2,thickness=2):

> display(p1,p2,p3);


chap7__109.pngfigure 7.17 : diagramme de bifurcation de Hopf

Un exemple physique est donné par les oscillations de Van Der Pol.

La bifurcation de Hopf décrite ici est supercritique, venant du fait que l'orbite périodique qui apparait en a = 0 est stable. Expérimentalement, elle se manifeste par une transition douce, le système commençant à osciller avec une amplitude croissante lorsque l'on passe la valeur a = 0.

On peut avoir également des bifurcations de Hopf sous-critiques obtenues en changeant stabilité et instabilité dans le diagramme de la bifurcation de Hopf (en changeant éventuellement le signe de a).

Combinée à une bifurcation selle-noeud, une bifurcation de Hopf sous-critique peut mener à un phénomène d'hystérésis.

début chapitre

Phénomène d'hystérésis

On prend l'exemple suivant :
MATH

La seconde équation indique que le point tourne autour de l'origine à vitesse constante. Voyons comment varie r en fonction du temps suivant les valeurs de a. Une valeur fixe de r correspondra à un mouvement circulaire uniforme.

Partons de a < 0 à gauche, par exemple a = -1,01, et prenons 2 valeurs initiales 0,3 et 1,5 :

> phaseportrait({D(r)(t)=-1.01*r+2*r^3-r^5},{r},

t=0..20,[[r(0)=1.5],[r(0)=0.3]],stepsize=0.1,title=''a=-1,01'');


chap7__111.pngfigure 7.18 : r en fonction du temps avec a = -1,01

On voit que r tend vers la valeur 0 pour toute valeur initiale et l'origine est un point fixe stable du flot de l'équation différentielle.

Augmentons la valeur de a à -0,99 :

> phaseportrait({D(r)(t)=-0.99*r+2*r^3-r^5},{r},t=0..6,

[[r(0)=1.5],[r(0)=0.3]],stepsize=0.1,title=''a=0,99'');


chap7__112.pngfigure 7.19 : r en fonction du temps pour a = -0,99

On a cette fois deux attracteurs, l'origine et un cercle de rayon proche de 1,1, et un cercle repousseur de rayon proche de 0,95. On a, pour a = -1, une bifurcation selle-noeud avec création de 2 trajectoires périodiques, l'une stable et l'autre instable en O.

Ce comportement persiste tant que a < 0. Voyons pour a > 0, par exemple a = 0,1 :

> phaseportrait({D(r)(t)=0.1*r+2*r^3-r^5},{r},

t=0..6,[[r(0)=0.3]],stepsize=0.1,title=''a=0,1'');


chap7__113.pngfigure 7.20 : r en fonction du temps pour a = 0,1

L'origine est devenue instable. On a en O une bifurcation de Hopf sous-critique :en venant de a > 0, l'origine instable devient stable, cependant que prend naissance une trajectoire périodique instable qui persiste en s'aggrandissant jusqu'à la bifurcation selle-noeud pour a = -1.

On obtient le diagramme de bifurcation suivant :

> restart:with(plots):

> solve({0=a*r+2*r^3-r^5},r);
MATH

> p1:=plot(0,a=-1.5..0,thickness=2):

> p2:=plot(0,a=0..0.5,thickness=2,linestyle=2):

> p3:=plot(sqrt(1+sqrt(1+a)),a=-1..0.5,thickness=2):

> p4:=plot(sqrt(1-sqrt(1+a)),a=-1..0,thickness=2,linestyle=2):

> display(p1,p2,p3,p4);


chap7__115.pngfigure 7.21 : diagramme d'hystérésis

Si a passe d'une valeur < -1 à une valeur > 1 puis revient à son point de départ, le point reste à l'origine tant que a < 0 ;lorsqu'il passe par 0, le point saute sur le cercle de rayon > 1 ;lorque a diminue, il reste sur le cercle tant que a > -1 ;lorsqu'il passe la valeur -1, il saute à l'origine.

Le système ne suit pas le même chemin à l'aller et au retour. Il y a hystérésis. De nombreux systèmes physiques présentent ce phénomène (hystérésis magnétique, comparateur à hystérésis en électronique...).

début chapitre

retour index