retour index

chapitre 6

Systèmes dynamiques Hamiltoniens

Matrice jacobienne

Le modèle de Hénon

Le modèle de Mira

L'application standard

Hamiltonien

L'hamiltonien de Hénon-Heiles

Exercices

 

On peut diviser les systèmes dynamiques en deux grandes catégories ayant des propriétés très distinctes :les systèmes dissipatifs, qui sont soumis à des frottements, et les systèmes non dissipatifs, ou Hamiltoniens, sans frottements ni entretien, dont l'énergie se conserve au cours du temps. Les mouvements des corps célestes, planètes, étoiles, astéroïdes dont les frottements sont négligeables sont des exemples de mouvements Hamiltoniens.

Dans le plan de phase (ou dans une section de poincaré si le nombre de degrés de liberté dépasse 2), le fait qu'un mouvement soit Hamiltonien se voit par la conservation de l'aire.

Cette conservation de l'aire peut se faire de 2 façons :soit l'élément de surface considéré tourne autour d'un point fixe sans trop se déformer et la trajectoire est stable ;soit il s'allonge exponentiellement dans une direction tout en se contractant exponentiellement dans la direction perpendiculaire ;la trajectoire est alors instable puisqu'un écart initial est très vite amplifié et le mouvement devient chaotique.

Pour distinguer un mouvement dissipatif ou entretenu d'un mouvement hamiltonien, il faut calculer le déterminant de la matrice jacobienne de l'application.

Matrice jacobienne

Pour qu'une application linéaire conserve les surfaces (ou les volumes dans le cas de 3 dimensions), il faut que la valeur absolue du déterminant associé à la matrice de l'application soit égale à l'unité.

Pour une application non linéaire, son comportement au voisinage d'un point peut se décrire à l'aide de sa partie linéaire, c'est-à-dire qu'on la remplace par l'application linéaire telle que
MATH

p est un vecteur à n dimensions, h un petit vecteur et Df(p) est la matrice jacobienne
MATH

des dérivées partielles évaluées en p.

On dit que l'application f conserve les aires si MATH pour tout p.

Si MATH alors il y a contraction des aires dans le cas d'un système dissipatif, et, si MATH il y a dilatation des aires dans la cas d'un système entretenu. Dans le cas du régime forcé, l'entretien compense les frottements en régime permanent mais l'espace de phase a une dimension supplémentaire qui est le temps et les trajectoires ne sont plus fermées ;ce ne sont pas des systèmes hamiltoniens.

début chapitre

Le modèle de Hénon

Comme premier exemple de système Hamiltonien, on va prendre le modèle de Hénon.

L'application de Hénon est une itération à 2 dimensions qui peut se mettre sous diverses formes, notamment
MATH

La matrice jacobienne correspondante s'écrit :
MATH

Le déterminant vaut 1, ce qui signifie que, sous la forme proposée, l'application de Hénon conserve la surface.

Traçons quelques trajectoires de cette application pour des valeurs initiales différentes de x, la valeur initiale de y restant nulle :

> restart:with(plots):

> a:=0.24:b:=0.9708:

> liste1:=op([]):for j in [0.1,0.2,0.3,0.4,0.5,0.6,0.62,0.7,0.71,0.715]

do: x:=j:y:=0:liste:=x,y:for i to 1000 do

z:=x:x:=y:y:=-z+2*a*y+b*y^2:liste:=liste,x,y od:

p:=pointplot([liste],color=red):liste1:=liste1,p od:

> display(liste1,color=red);


chap6__8.pngfigure 6.1 : quelques trajectoires d'une application de Hénon conservant la surface

Quelques traits sautent immédiatement aux yeux :tout d'abord, en l'absence de frottement, les trajectoires ne convergent pas vers un attracteur, et, à chaque condition initiale correspond une trajectoire différente. On a affaire en quelque sorte à des régimes transitoires qui ne faiblissent pas.

La figure se compose au voisinage du centre de courbes fermées entourant l'origine qui est un point fixe stable (centre). La transformation de Hénon est alors proche d'une rotation autour de l'origine d'un angle qui n'est pas très loin de $-2\pi /5$ ;le point fait un peu plus d'un tour en 5 itérations, comme on peut le voir sur la liste des points calculés. Plus on s'éloigne du centre et plus on se rapproche de la synchronisation. Au voisinage de celle-ci, on observe un ensemble de 5 îles reproduisant l'île centrale, entouré à son tour par une courbe fermée séparant la zone structurée de la zone chaotique qui s'étend au delà.

La zone initiale comprenant le point fixe (0,0) et les cercles qui l'entourent est la résonance principale ;la résonance est entourée des 5 îlots qui sont des résonances secondaires, correspondant à un accrochage d'ordre 5 :le système passe d'un îlot à l'autre et revient à l' îlot initial après 5 itérations ;il est synchronisé au centre de l'îlot sur une période qui est 5 fois celle de l'itération. C'est en fait la synchronisation qui structure les systèmes Hamiltoniens.

Chaque îlot a la même structure que la résonance principale et il est entouré à son tour d'autres îlots trop petits pour être vus sur la figure ;la figure est autosimilaire et possède une stucture fractale. Lorsqu'on s'éloigne, le système se désynchronise, et on entre dans la zone de chaos à grande échelle (zone stochastique). Il existe également d'autres zones stochastiques localisées entre les résonances comme nous allons le voir.

Pour la valeur initiale x = 0,715 et y = 0, on voit sur la figure ci-dessus (il s'agit de la trajectoire extérieure) que la trajectoire est chaotique. Pour la valeur initiale x = 0,72 et y = 0, on obtient :

> x:=0.72:y:=0:liste:=x,y:for i to 66 do

z:=x:x:=y:y:=-z+2*a*y+b*y^2:liste:=liste,x,y od:

> pointplot([liste],color=red);


chap6__10.pngfigure 6.2 : trajectoire chaotique partant de x = 0,72 et y = 0

La trajectoire est chaotique et diverge rapidement après le 66$^{i\grave{e}me}$ point. La figure s'arrête au delà.

Structure des résonances

On quitte la résonance principale lorsque l'on arrive à un ensemble de 5 points fixes instables, qui sont des point-selles, correspondant à la synchronisation 5/1, c'est-à-dire que le point revient sur lui-même au bout de 5 itérations. Un des point-selles a des coordonnées proches et légèrement supérieures à x = y = -0,3443666 :

> x:=-0.3443666:y:=-0.3443666:liste:=x,y:for i to 2000 do

z:=x:x:=y:y:=-z+2*a*y+b*y^2:liste:=liste,x,y od:

> pointplot([liste],color=red);


chap6__12.pngfigure 6.3 : trajectoire pour x = y = -0,3443666

Les 5 point-selles occupent les 5 sommets de la figure. Augmentons très légèrement la valeur de x et y :

> x:=-0.3443667:y:=-0.3443667:liste:=x,y:for i to 2000 do

z:=x:x:=y:y:=-z+2*a*y+b*y^2:liste:=liste,x,y od:

> pointplot([liste],color=red);


chap6__13.pngfigure 6.4 : trjectoire pour x = y = -0,3443667

La trajectoire s'est brusquement agrandie et englobe les territoires des 5 îles qui vont se former par la suite ;on observe en fait sur la figure 6.4 les variétés stable et instable des point-selles (voir chapitre 8).

> liste1:=op([]):for j in [0.42875,0.47,0.52,0.56] do:

x:=j:y:=0:liste:=x,y:for i to 1000 do

z:=x:x:=y:y:=-z+2*a*y+b*y^2:liste:=liste,x,y od:

p:=pointplot([liste],color=red):liste1:=liste1,p od:

> display(liste1,color=red);


chap6__14.pngfigure 6.5 : structure des îles

Les centres des îles sont 5 autres points fixes qui sont stables (centres).

La trajectoire de la séparatrice entre la résonance principale et les îles est chaotique ; pour le voir, on aggrandit au voisinage d'un point fixe instable :

> x:=-0.3443668:y:=-0.3443668:liste:=x,y:for i to 4000 do

z:=x:x:=y:y:=-z+2*a*y+b*y^2:liste:=liste,x,y od:

> pointplot([liste],color=red,view=[-0.4..-0.3,-0.4..-0.3]);


chap6__15.pngfigure 6.6 : trajectoire chaotique d'un morceau de la séparatrice

La structure engendrée par l'itération de Hénon consiste donc en une résonance principale, donnant naissance à des résonances secondaires, donnant à leur tour naissance à d'autre résonances suivant une structure emboitée. Le centre des résonances est occupée par des points fixes stables correspondant à des trajectoires périodiques synchronisées sur l'itération. La séparation entre les résonances se fait par des trajectoires chaotiques au voisinage de point-selles synchronisés mais instables.

En partant du centre, on rencontre donc d'abord des point-selles qui vont former la frontière en forme d'anneau formée de 2 bandes torsadées (figure 6.4), puis des points fixes stables au centre des îles. On a des zones chaotiques en bordure des îles et une zone chaotique à grande échelle à l'extérieur des résonances. Cette structure se retrouve en principe dans tous les mouvements hamiltoniens.

Les courbes fermées s'appellent les courbes de KAM. Nous y reviendrons.

début chapitre

Le modèle de Mira

Il s'agit d'une itération simple qui mène à de très belles figures et à une compréhension visuelle du comportement d'un système Hamiltonien.

On considère l'itération
MATH

F(x) peut prendre diverses formes. On prendra d'abord
MATH

Lorsque b = 1, cette application conserve la surface.

Les courbes obtenues pour les diverses conditions initiales sont des courbes fermées, des cycles périodiques, des îles et des courbes chaotiques.

Si a = 1, F(x) = x et le système est parfaitement régulier.

Lorsque la valeur de a diminue, le dessin devient intéressant et le chaos apparait de plus en plus.

a = 0,9

Traçons un certain nombre de trajectoires pour a = 0,9 correspondant à diverses conditions initiales, les valeurs initiales de x étant mises dans la liste init et les valeurs initiales de y nulles. La valeur de $x_{n}$ est notée z de façon à pouvoir s'en servir dans le calcul de $y_{n+1}$ :

> restart:with(plots):

> init:=[4,8,10.5,18,25,30]:liste1:=op([]):a:=0.9:b:=1:

for j in init do x:=j:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=0:liste:=x,y:

for n to 1000 do

z:=x:x:=b*y+w :w:=a*x+(1-a)*2*x^2/(1+x^2):y:=w-z:

liste:=liste,x,y od:

p:=pointplot([liste],style=point,color=red):liste1:=liste1,p od:

> display(liste1);


chap6__20.pngfigure 6.7 : trajectoires hamiltoniennes du modèle Mira avec a = 0,9

On constate un accrochage sur la période 14 :le centre des îles constitue un cycle périodique de période 14, c'est-à-dire que le point revient à la même position après 14 itérations.

a = 0,7

Recommençons le même travail pour a = 0,7 :

> restart:with(plots):

> init:=[3,5,7,9,11]:liste1:=op([]):a:=0.7:b:=1:for j in init do

x:=j:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=0:liste:=x,y:

for n to 1000 do

z:=x:x:=b*y+w:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=w-z:

liste:=liste,x,y od:

p:=pointplot([liste],style=point,color=red):liste1:=liste1,p od:

> x:=9:y:=1.8:a:=0.7:b:=1:w:=a*x+(1-a)*2*x^2/(1+x^2):liste:=x,y:

for n to 1000 do

z:=x:x:=b*y+w:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=w-z:

liste:=liste,x,y od:(tracé des îles)

> p:=pointplot([liste],style=point,color=red):

> display(liste1,p);


chap6__21.pngfigure 6.8 : modèle Mira avec a = 0,7

La stucture devient plus complexe :la figure est centrée sur le point (1,0) qui est un point fixe. On a autour du centre la résonance principale comprenant elle-même des accrochages (on distingue l'accrochage 10) ;puis une zone chaotique la sépare de l'accrochage 8 bien visible.

La zone chaotique pas très étendue entoure les îlots de l'accrochage 8. Elle prend naissance aux points fixes instables qui séparent les îlots.

a = 0,3

Pour a = 0,3, cela donne :

> restart:with(plots):

> init:=[3,7,12,20,-12]:liste1:=op([]):a:=0.3:b:=1:for j in init

do x:=j:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=0:liste:=x,y:

for n to 1000 do

z:=x:x:=b*y+w:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=w-z:

liste:=liste,x,y od:

p:=pointplot([liste],style=point,color=red):liste1:=liste1,p od:

> display(liste1);


chap6__22.pngfigure 6.9 : modèle Mira avec a = 0,3

On distingue une première zone centrale chaotique entourant le point fixe (1,0) ayant une forme rappellant celle d'un poisson, suivie d'une deuxième zone chaotique s'arrêtant à l'accrochage d'ordre 5.

Dessinons une trajectoire chaotique dans la première zone chaotique :

> x:=+1.5:y:=0:a:=0.3:b:=1:w:=a*x+(1-a)*2*x^2/(1+x^2):

liste:=x,y:

> for n to 1000 do

z:=x:x:=b*y+w:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=w-z:

liste:=liste,x,y od:

> pointplot([liste],style=point,color=red);


chap6__23.pngfigure 6.10 : trajectoire chaotique dans la zone centrale

Dessinons enfin, pour a = 0,31, une trajectoire de ''chaos esthétique'' :

> restart:with(plots):

> x:=12:y:=0:a:=0.31:b:=1:w:=a*x+(1-a)*2*x^2/(1+x^2):

liste:=x,y:

> for n to 2000 do

z:=x:x:=b*y+w:w:=a*x+(1-a)*2*x^2/(1+x^2):y:=w-z:

liste:=liste,x,y od:

> pointplot([liste],style=point,color=black);


chap6__24.pngfigure 6.11 : chaos ''esthétique'' pour a = 0,31


début chapitre

L'application standard

Il s'agit d'une application définie sur un carré de côté unité, x variant de 0 à 1 et y de -0,5 à 0.5. On identifie les côtés gauche et droit du carré, ce qui revient à remplacer x par x - 1 si x >1 et x par x + 1 si x <0 ;de même, on identifie les côtés bas et haut, ce qui revient à remplacer y par y - 1 si y >0,5 et y par y + 1 si y <-0,5. Dans ces conditions, l'application standard s'écrit :
MATH

Cette fonction est périodique de période 1 à la fois en x et y et l'espace de phase est en fait le tore obtenu en collant les bords droit et gauche du carré ainsi que les bords supérieur et inférieur. a est un paramètre de contrôle que l'on peut varier.

La matrice jacobienne s'écrit :
MATH

Son déterminant est 1, ce qui signifie que l'application standard est une famille d'applications à un paramètre conservant l'aire.

Pour a = 0, on aura pour les différentes valeurs de y des droites horizontales.

Pour a = 0,4, traçons 18 orbites, la valeur initiale de x étant fixée à 0,4 et les valeurs initiales de y variant de -0,9 à 0,9 par pas de 0,1 :

> restart:with(plots):

> a:=0.3:b:=evalf(2*Pi):

> liste1:=op([]):for j to 18 do x:=0.4:y:=(j-10)/20:liste:=x,y:

for i to 400 do z:=x:x:=x+y:if x>1 then x:=x-1

elif x<0 then x:=x+1 fi:

y:=y+a/b*sin(b*(z+y)):if y>0.5 then y:=y-1

elif y<-0.5 then y:=y+1 fi:

liste:=liste,x,y od:p:=pointplot([liste],color=red):

liste1:=liste1,p:od:

> display(liste1,view=[0..1,-0.5..0.5]);


chap6__27.pngfigure 6.12 : application standard pour a = 0,4

La zone entourant le point fixe (centre) (0,0) est la résonance principale. A chaque itération, le point se déplace sur la courbe fermée invariante.

Remplaçons dans le programme a par 0,8 :


chap6__28.pngfigure 6.13 : application standard pour a = 0,8

On voit apparaître des accrochages à l'intérieur de la résonance principale (d'ordre 8 par exemple). La frontière de la résonance principale devient chaotique et des résonances secondaires existent à l'extérieur, correspondant à des accrochages d'ordre 3, et 2 sur les bords (ne pas oublier que l'on identifie les côtés opposés).

Voyons pour a = 1,2 :


chap6__29.pngfigure 6.14 : application standard pour a = 1,2

La zone chaotique est de plus en plus importante, le nombre d'accrochages augmente dans les résonances principale et secondaires. Traçons une seule trajectoire pour a = 7 :

> restart:with(plots):

> a:=7:b:=evalf(2*Pi):

> x:=0.4:y:=0:liste:=x,y: for i to 2000 do

z:=x:x:=x+y:if x>1 then x:=x-1 elif x<0 then x:=x+1 fi:

y:=y+a/b*sin(b*(z+y)):if y>0.5 then y:=y-1

elif y<-0.5 then y:=y+1 fi: liste:=liste,x,y od:

> pointplot([liste],color=red);


chap6__30.pngfigure 6.15 : application standard pour a = 7

Une seule trajectoire chaotique emplit tout l'espace.

Les courbes fermées à l'intérieur des résonances s'appellent courbes de KAM (ce sont les initiales de A.Kolmogorov, V.Arnold et J.Moser, créateurs de la théorie maintenant appelée KAM).

début chapitre

Hamiltonien

La mécanique classique enseigne que, pour tout système non dissipatif, on peut trouver une fonction H, appelée Hamiltonien du système, dépendant des coordonnées d'espace généralisées notées $q_{i}$ et des coordonnées de moment conjuguées notées $p_{i}.$

Le calcul des variations permet d'établir les équations du mouvement à partir de l'Hamiltonien du système sous la forme :
MATH

Lorsque la fonction H ne dépend pas explicitement du temps, on vérifie que MATH et H = cte s'interprète comme l'énergie invariante du système dans les conditions données.

A partir des équations de Hamilton, on montre qu'il y a conservation de l'aire dans le diagramme de phase.

Un exemple en est le pendule simple (masse suspendue à un fil dont l'autre extrémité est fixe) décrit par la distance $x=l\theta $ avec la verticale mesurée sur le cercle et le moment cinétique MATH

L'énergie du pendule, somme de son énergie cinétique et de son énergie potentielle, est :
MATH

Les équations de Hamilton s'écrivent :
MATH

La première mène à l'équation différentielle du mouvement MATH et la seconde conduit à MATH

Il existe, dans Maple, 4 commandes qui ont été créées dand la bibliothèque DEtools pour tracer les sections de Poincaré des mouvements hamiltoniens ;ce sont

On consultera avec profit l'aide en ligne et les exemples proposés.

début chapitre

L'Hamiltonien de Hénon-Heiles

C'est l'Hamiltonien proposé par Michel Hénon et son étudiant Carl Heiles dans un modèle d'évolution des étoiles dans une galaxie. Il s'écrit :
MATH

Cherchons les équations de Hamilton associées :

> restart:with(plots):with(DEtools):

> H := 1/2*(p1^2+p2^2+q1^2+q2^2)+q1^2*q2-q2^3/3;

>ha:= hamilton_eqs(H);
MATH

C'est un système d'équations différentielles du premier ordre couplées et non linéaires.

Traçons une trajectoire d'énergie égale à 1/12. Pour cela, on cherche d'abord avec la commande generate_ic des conditions initiales menant à une énergie 1/12. On fixe $p_{2},q_{1}$ et $q_{2}$ et la commande calcule $p_{1}$ ;on ne demande qu'une seule condition initiale :

> a:=generate_ic(H,{t=0,p2=0.1,q2=0,q1=0,energy=1/12},1);
MATH

On trace ensuite la section de Poincaré, ici l'ensemble des points d'intersection de la trajectoire avec le plan $q_{2}=0$ :

>poincare(H,t=-300..300,a, stepsize=.1,

iterations=2,scene=[q1,p2]);


chap6__48.pngfigure 6.16 : section de Poincaré avec H = 1/12

La précision du tracé s'améliore avec le nombre d'itérations (mais le temps de calcul augmente également ! ).

Les points se répartissent sur une courbe régulière, comme on peut le vérifier en traçant la trajectoire à 3 dimensions :

> F:=poincare(H,t=-100..100,a, stepsize=.1,iterations=1,

scene=[p2,q1,q2],3):

> zoom(F,-0.5..0.5,-0.5..0.5,-0.5..0.5);


chap6__49.pngfigure 6.17 : trajectoire à 3 dimensions avec H = 1/12

Faire tourner la figure pour retrouver la section de Poincaré.

Reprenons les mêmes constructions avec une énergie de 1/6 :

> a:=generate_ic(H,{t=0,p2=0.1,q2=0,q1=0,energy=1/6},1);
MATH

> poincare(H,t=-200..200,a, stepsize=.1,iterations=1,

scene=[p1,q1]);


chap6__51.pngfigure 6.18 : section de Poincaré avec H = 1/6

La trajectoire semble chaotique, ce que semble aussi nous confirmer le tracé à 3 dimensions :

> F:=poincare(H,t=-100..100,a, stepsize=.1,iterations=1,

scene=[p1,q1,q2],3):

>zoom(F,-0.6..0.6,-0.6..0.6,-0.6..0.6);


chap6__52.pngfigure 6.19 : trajectoire à 3 dimensions, avec H = 1/6

On peut également tracer la trajectoire réelle dans le plan MATH avec phaseportrait en utilisant les équations de Hamilton contenues dans ha et les conditions initiales dans a :

>phaseportrait(ha,t=-50..50,[[q1(0)=0,q2(0)=0,p1(0)=.568,

p2(0)=0.1]],stepsize=0.1,scene=[q1,q2]);


chap6__54.pngfigure 6.20 : trajectoire réelle avec H = 1/6

Traçons également $q_{1}$ en fonction du temps :

>phaseportrait(h,t=-150..150,[[q1(0)=0,q2(0)=0,p1(0)=.568,

p2(0)=0.1]],stepsize=0.1,scene=[t,q1]);


chap6__57.pngfigure 6.21 : $q_{1}$ fonction chaotique du temps avec H = 1/6

Voyons l'évolution de la section de Poincaré avec une énergie croissante ;l'énergie augmente de 1/24 à 1/6 ;pour chaque valeur de l'énergie, on génère 3 conditions initiales et on prend la section de Poincaré. On regroupe les tracés dans un tableau que l'on trace :

> for h in [1/24,1/18,1/12,1/8,1/7,1/6] do

ics[h] := generate_ic(H,{t=0,p2=0.1,q2=-0.2..0.2,q1=-0.2..-0.1,

energy=h},3): F[h]:=poincare(H,t=-100..100,ics[h],

stepsize=.1,iterations=2,scene=[p2=-0.5..0.5,q2=-0.5..0.5]):od:

> F1 := array([[F[1/24],F[1/18],F[1/12]],[F[1/8],F[1/7],F[1/6]]]):

> display(F1,axes=none,labels=[ ` `, ` `]);


chap6__58.pngfigure 6.22 : évolution de la section de Poincaré avec l'énergie croissante

Pour H = 1/24, les trajectoires sont régulières, en fait quasipériodiques, c'est-à-dire faisant intervenir plusieurs fréquences. Petit à petit, le chaos envahit toute la section de Poincaré en détruisant les tores de KAM.

Pour terminer, détaillons le cas H = 1/12 en prenant 6 conditions initiales :

> a:=generate_ic(H,{t=0,p2=0.1,q2=-0.2..0.2,q1=-0.2..-0.1,

energy=1/12},6);

> poincare(H,t=-200..200,a, stepsize=.1,iterations=1,

scene=[p2=-0.5..0.5,q2=-0.5..0.5]);


chap6__59.pngfigure 6.23 : détails de la section de Poincaré pour H = 1/12

On remarque que la résonance du haut de la figure contient un accrochage d'ordre 6 et un accrochage proche de la frontière de la résonance d'ordre 14 ;également un comportement chaotique aux frontières des diverses résonances.

La théorie des systèmes Hamiltoniens trouve des confirmations dans la mécanique céleste. La résonance y est omniprésente. On sait que la lune présente toujours la même face à la terre ;elle présente une résonance 1/1 entre sa période de rotation propre et sa période de rotation autour de la terre.

Mercure tourne sur elle-même en 59 jours et autour du soleil en 88 jours, présentant une résonance 2/3. Il existe de nombreux autres exemples.

On sait qu'entre Mars et Jupiter existe une ceinture d'astéroïdes, mais ces astéroïdes ne sont pas répartis uniformément. En particulier, il y a des lacunes, les lacunes de Kirkwood, où il n'y a pas d'astéroïdes. Ces lacunes correspondent à des résonances entre la période de rotation de l'astéroïde autour du soleil et celle de Jupiter, par exemple les résonances 2/1, 3/1 ,4/1, 5/2 et 7/2.

La lacune correspondant à la résonance 3/1 a été expliquée par le fait que l'influence de Jupiter peut envoyer par une orbite chaotique l'astéroïde au voisinage de Mars qui l'envoie à son tour dans l'espace.

début chapitre

Exercices

Exercice 1

Hamiltonien de Toda

L'Hamiltonien de Toda s'écrit :


MATH

Tracer la section de Poincaré dans le plan MATH On prendra pour conditions initiales à t = 0 :MATH et $q_{2}=0.$ On prendra t de -150 à 150, le pas d'intégration fixé à 0,05 et le nombre d'itérations à 2.

Tracer ensuite la trajectoire à 3 dimensions dans l'espace MATH Faire tourner la figure pour retrouver la forme de la section de Poincaré.

Exercice 2

Un Hamiltonien de la Relativité Générale

On utilise en Relativité Générale l'Hamiltonien
MATH

Tracer sa section de Poincaré avec les valeurs initiales à t = 0 :MATH et $q_{2}=0.$

Tracer ensuite la trajectoire dans l'espace MATH

Réponses aux exercices

Exercice 1

> H := 1/2*(p1^2 + p2^2) + 1/24*(exp(2*q2+2*sqrt(3)*q1)

+ exp(2*q2-2*sqrt(3)*q1) + exp(-4*q2))-1/8;

>poincare(H, t=-150..150, {[0,.1,1.4,.1,0]}, stepsize=.05,

iterations=2);


chap6__69.pngfigure 6.24 : section de Poincaré de l'Hamiltonien de Toda

> poincare(H,t=-100..100, {[0,.1,1.4,.1,0]},stepsize=.1,

iterations=2,scene=[p1=-1.5..1.5,q1=-1.5..1.5,q2=-1.2..1.3],3);


chap6__70.pngfigure 6.25 : trajectoire à 3 dimensions de l'Hamiltonien de Toda

Exercice 2

>H := 1/2*(-p1^2-q1^2+0.25*q1^4+p2^2+q2^2+

0.65^2*q1^2*q2^2);

>poincare(H, t=-150..150, {[0,0.1,0.1,.1,0]}, stepsize=.1,

iterations=2);


chap6__71.pngfigure 6.26 : section de Poincaré de l'Hamiltonien de la Relativité Générale

>P:=poincare(H, t=-50..50, {[0,0.1,0.1,0.1,0]}, stepsize=.1,

iterations=2,scene=[q1,q2,p1],3):

>zoom(P,-0.2..0.2,-0.2..0.2,-0.2..0.2);


chap6__72.pngfigure 6.27 : trajectoire à 3 dimensions

début chapitre

retour index